sip / PyQt5 빌드 for Maya 2017

환경 설정 
1. Developer Kit 다운로드 (Maya 2017 Update 3 - Developer Kit) 
2. C:\Users\사용자\에 devkitBase 폴더로 압축 해제한다.
3. \devkitBase\devkit\applications 폴더에 devkit과 mkspecs 폴더를 \Maya2017 폴더에 복사한다. (필요한 경우 덮어씌우기)


qt.conf 파일 수정
\Maya2017\bin 폴더 안에 qt.conf 파일 메모장으로 오픈한다.

[Paths]
Prefix=$(MAYA_LOCATION)
Libraries=lib
Binaries=bin
Headers=include/Qt
Data=.
Plugins=qt-plugins
Translations=qt-translations
Qml2Imports=qml

Headers 경로에서 /Qt 추가하고 저장한다.

각 마야 폴더들의 압축되어 있는 파일들을 푼다.
\Maya2017\include\qt-5.6.1-include.tar.gz 압축 파일을 \Maya2017\include\Qt에 압축을 푼다.
\Maya2017\mkspecs\qt-5.6.1-mkspecs.tar.gz 압축 파일을 본 폴더(mkspecs)에 압축을 푼다.


sip 빌드

현 시스템이나 Maya 버전에 맞게 수정 후 installSip.bat 저장한다.
installSip.bat(임의)

REM @echo off
set MAYAPYQTBUILD=%~dp0
REM set MAYAPYQTBUILD=%MAYAPYQTBUILD:~0,-1%
if exist v:\nul subst v: /d
subst v: "%MAYAPYQTBUILD%"

set SIPDIR=v:\sip-4.19.2
set MSVC_DIR=C:\Program Files (x86)\Microsoft Visual Studio 14.0
if ["%LIBPATH%"]==[""] call "%MSVC_DIR%\VC\vcvarsall" amd64

set MAYA_LOCATION=C:\Program Files\Autodesk\Maya2017
set INCLUDE=%INCLUDE%;%MAYA_LOCATION%\include\python2.7
set LIB=%LIB%;%MAYA_LOCATION%\lib

pushd %SIPDIR%
"%MAYA_LOCATION%\bin\mayapy" configure.py
nmake
nmake install
popd
pause

.bat 파일을 탐색기에서 우클릭 후 '관리자 권한으로 실행' 한다.



빌드 완료.

파일을 찾을 수 없다느니, 파일을 복사할 수 없다느니 하는 오류가 발생했는지 확인한다. 오류가 있으면 자신의 설치 경로들(VC 경로, 마야 설치 경로 등)을 확인 후 .bat 파일을 수정한다. '또한 잘못된 매개 변수입니다 - 드라이브명:'이 나오면 가상 드라이브 설정 오류이므로 도스 프롬프트에서 subst v: /d를 하여 가상 드라이브를 해제 시킨다.

마야을 실행 후 확인한다.

import sip

PyQt5 빌드

빌드 가이드에 아래 주의 사항이 있다. 

Note that the pyQT generated makefile are using the make macro <? while building 'pylupdate'. Unfortunately, it will hang forever on Windows, and will complain about an undefined macro <? ... This macro means to use the first build dependency file as argument, but nmake does not seems to like it. The script below will bypass the makefile rule, so it should work just fine.

그러나, 가이드에선 오타로 인해 사용할 수 없었고, Visual Studio Community 2015에서 빌드를 하려고 하였지만 되질 않아 Visual Studio Express 2012를 설치해야만 했다.

또한, Visual Studio Express 2012에서는 64bit 빌드를 사용할 수 없다. 허나 가능하게~ 

그러므로, Visual Studio Express 2012에서 빌드하였다.

Visual Studio Express 2012를 설치 한다.
1.설치 폴더 \Microsoft Visual Studio 11.0\VC\bin\x86_amd64 폴더를 amd64 폴더로 복사한다.
2.\amd64 폴더 안 vcvarsx86_amd64.bat 파일을 vcvars64.bat로 변경한다.

Maya 2017용 PyQt5 설치 스크립트를 찾아 조금 수정하였다.  

setup.bat 파일

REM @echo off

set MAYAVERSION=2017
set ADSKQTVERSION=5.6.1
set SIPVERSION=4.19.2
set PYQTVERSION=5.8.2
set MAYADRIVE=m:
set BUILDDRIVE=v:
 
if exist %MAYADRIVE%\nul subst %MAYADRIVE% /d
subst %MAYADRIVE% "C:\Program Files\Autodesk\Maya%MAYAVERSION%"
set MAYA_LOCATION=%MAYADRIVE%
 
set MAYAPYQTBUILD=%~dp0
rem Removing trailing \
set MAYAPYQTBUILD=%MAYAPYQTBUILD:~0,-1%
 
if exist %BUILDDRIVE%\nul subst %BUILDDRIVE% /d
subst %BUILDDRIVE% "%MAYAPYQTBUILD%\"
 
set SIPDIR=%BUILDDRIVE%\sip-%SIPVERSION%
set PYQTDIR=%BUILDDRIVE%\PyQt5_gpl-%PYQTVERSION%
rem set ADSKQTDIR=%BUILDDRIVE%\qt-%ADSKQTVERSION%
set QTDIR=%MAYA_LOCATION%
 
set PATH=%QTDIR%\bin;%PATH%
set MSVC_VERSION=2012
set MSVC_DIR=C:\Program Files (x86)\Microsoft Visual Studio 11.0
set QMAKESPEC=%QTDIR%\mkspecs\win32-msvc%MSVC_VERSION%
set _QMAKESPEC_=win32-msvc%MSVC_VERSION%
 
if ["%LIBPATH%"]==[""] call "%MSVC_DIR%\VC\vcvarsall" amd64
 
set INCLUDE=%INCLUDE%;%MAYA_LOCATION%\include\python2.7
set LIB=%LIB%;%MAYA_LOCATION%\lib

pause

installPyQt5.bat 파일

REM @echo off

set XXX=%~dp0
if ["%MAYAPYQTBUILD%"]==[""] call "%XXX%setup.bat"
 
set QMAKESPEC=%QTDIR%\mkspecs\%_QMAKESPEC_%
if not exist "%QMAKESPEC%\qmake.conf" (
     echo "You need to uncompress %MAYA_LOCATION%\mkspecs\qt-5.6.1-mkspecs.tar.gz !"
     goto end
)
if not exist "%MAYA_LOCATION%\include\Qt\QtCore\qdir.h" (
    echo "You need to uncompress %MAYA_LOCATION%\include\qt-5.6.1-include.tar.gz in %MAYA_LOCATION%\include\Qt !"
     goto end
)
findstr /L /C:"Headers=include/Qt" "%MAYA_LOCATION%\bin\qt.conf" >nul 2>&1
if ERRORLEVEL 1 (
    echo "You need to edit %MAYA_LOCATION%\bin\qt.conf to use 'Headers=include/Qt'"
    goto end
)
findstr /L /C:"-lqtmain -lshell32" "%QTDIR%\mkspecs\common\msvc-desktop.conf" >nul 2>&1
if ERRORLEVEL 1 (
    echo "You need to edit %QTDIR%\mkspecs\common\msvc-desktop.conf to use 'QMAKE_LIBS_QT_ENTRY     = -lqtmain -lshell32'"
    goto end
)
if not exist "%MAYA_LOCATION%\include\Qt\qtnfc.disabled" (
    echo "You need to rename %MAYA_LOCATION%\include\Qt\qtnfc to %MAYA_LOCATION\include\Qt\qtnfc.disabled"
     goto end
)
     
pushd %PYQTDIR%
 
"%MAYA_LOCATION%\bin\mayapy" configure.py --spec %QMAKESPEC% LIBDIR_QT="%QTDIR%\lib" INCDIR_QT="%QTDIR%\include\Qt" MOC="%QTDIR%\bin\moc.exe" --sip="%QTDIR%\Python\sip.exe" --sip-incdir="%QTDIR%\Python\include" -w --no-designer-plugin
nmake
nmake install
popd

:end

subst m: /d
subst v: /d

pause

1. \Maya2017\mkspecs\common\msvc-desktop.conf 파일 수정

#중략...
QMAKE_LIBS_QT_ENTRY = -lqtmain -lshell32
#중략...

2. \Maya2017\include\Qt\qtnfc 폴더를 qtnfc.disabled로 변경


installPyQt5.bat(임시) 파일을 우클릭 후 '관리자 권한으로 실행' 한다.
1. '계속하려면 아무 키나 누르십시오...' 나오면 아무키 누른다.
2. Python Licence가 나오면 yes



빌드 시작 (시간이 제법 걸린다.)


마야 실행 후 확인한다.

import PyQt5

복사해서 사용될지 모르겠지만 패키징 파일을 첨부한다.(PyQt5&sip_pacakage_for_Maya2017.zip) \Maya2017\Python 폴더에 넣어준다.(덮어씌운다는 메세지가 나온다면 무시) 빌드 된 각각의 파일은 PyQt5_builed_Maya2017.zip, sip_builed_Maya2017.zip

참고 사이트들
https://stackoverflow.com/questions/41755976/pyqt5-maya-2017
http://justinfx.com/2011/11/09/installing-pyqt4-for-maya-2012-osx
http://justinfx.com/2011/01/07/installing-pyqt-for-maya-2011-osx

참고 할 사이트들
https://fredrikaverpil.github.io/2016/07/25/dealing-with-maya-2017-and-pyside2
https://fredrikaverpil.github.io/2016/07/25/developing-with-qt-py